#ifdef SENSOR_BMP280
//Connect SCL to D1, SDA to D2, GND and 3v3
#include "sensor_bmp280.h"



Sensor_BMP280::Sensor_BMP280()
{
    bmp280 = new Adafruit_BMP280();
}

void Sensor_BMP280::init() //Things to be done during setup()
{    
    Serial.println("initializing bmp280");
    if (!bmp280->begin(0x76)){
      Serial.println("#ERROR: bmp280 init fail\n");
    }else{
      init_ok=true; //stays false if init failed, sensor will not be read in loop

      bmp280->setSampling(Adafruit_BMP280::MODE_NORMAL,     /* Operating Mode. */
                  Adafruit_BMP280::SAMPLING_X2,     /* Temp. oversampling */
                  Adafruit_BMP280::SAMPLING_X16,    /* Pressure oversampling */
                  Adafruit_BMP280::FILTER_X16,      /* Filtering. */
                  Adafruit_BMP280::STANDBY_MS_500); /* Standby time. */
    }
}

//Also called during setup()
void Sensor_BMP280::setSettings_Temperature(float minchange, unsigned long senddelaymax, unsigned long readdelay)
{
    data_temperature.minchange=minchange;
    data_temperature.senddelaymax=senddelaymax;
    data_temperature.readdelay=readdelay;
}

//Also called during setup()
void Sensor_BMP280::setSettings_Pressure(float minchange, unsigned long senddelaymax, unsigned long readdelay)
{
    data_pressure.minchange=minchange;
    data_pressure.senddelaymax=senddelaymax;
    data_pressure.readdelay=readdelay;
}

//Called during setup
void Sensor_BMP280::advertise(HomieNode& p_sensorNode)
{
    sensorNode = &p_sensorNode;
    sensorNode->advertise("temperature");
    sensorNode->advertise("pressure");
}

void Sensor_BMP280::sensorloop()
{
  if (init_ok) {
    loop_BMP280_temperature();
    loop_BMP280_pressure();
  }
}

void Sensor_BMP280::loop_BMP280_temperature()
{
  sensordata &d=data_temperature;
  bool _changed=false;  

  if (millis() >= (d.lastreadtime+d.readdelay)) {
    d.value = bmp280->readTemperature();
    if (fabs(d.lastsentvalue-d.value)>=d.minchange){
      _changed=true;
    }
    d.lastreadtime=millis();
  }

  if (_changed || millis() >= (d.lastsent+d.senddelaymax)) {
    Serial.print("Sending bmp280_temperature. reason=");
    if (_changed) Serial.println("change"); else Serial.println("time");
    

    if (!(isnan(d.value) == 1)){ //success
      sensorNode->setProperty("temperature").send(String(d.value));
      Homie.getLogger() << "temperature " << ": " << d.value << endl;    
      d.lastsentvalue=d.value;
    }

    d.lastsent=millis();
  }
}

void Sensor_BMP280::loop_BMP280_pressure()
{
  sensordata &d=data_pressure;
  bool _changed=false;
  
  if (millis() >= (d.lastreadtime+d.readdelay)) {
    d.value = bmp280->readPressure()/100.0;
    if (fabs(d.lastsentvalue-d.value)>=d.minchange){
      _changed=true;
    }
    d.lastreadtime=millis();
  }

  if (_changed || millis() >= (d.lastsent+d.senddelaymax)) {
    Serial.print("Sending bmp280_pressure. reason=");
    if (_changed) Serial.println("change"); else Serial.println("time");

    if (!(isnan(d.value) == 1)){ //success
      Homie.getLogger() << "pressure " << ": " << d.value << endl;
      sensorNode->setProperty("pressure").send(String(d.value));
      d.lastsentvalue=d.value;
    }
    d.lastsent=millis();
  }
}


#endif